**Macro**

directory = getDirectory("Choose a Directory "); // prompts for directory with the images

list = getFileList(directory);

// for-loop below processes the files in the specified folder and outputs the quantification results in a table that can be copy/pasted into Excel

for (i=0; i<list.length; i++) {

 path = directory+list[i];

 showProgress(i, list.length);

 open(path); // opens the image to be processed; these are typically basic images, such as jpg, without any metadata or size calibration

 if (nImages>=1) {

 imagename = list[i];

 selectImage(imagename);

 run("Set Scale...", "distance=35 known=200 pixel=1 unit=nm"); // calibrate the size of the image - for example, use the scale-bar length in pixels

 makeRectangle(0, 0, 1022, 712); // pick the region of interest to analyze and to remove undesired sections, such as data field below (SEM voltage, scale bar, etc)

 run("Crop"); // removes the undesired region

 run("Median...", "radius=2"); // smooths the image, making thresholded areas more uniform

 setThreshold(0, 61); // the threshold values should be set by the user to produce the most accurate segmented mask image for quantification

 run("Convert to Mask"); // creates the binary black-white mask image based on the threshold values defined above

 // command below sets quantification categories: area and percent coverage of nano-features

 run("Set Measurements...", "area area\_fraction redirect=None decimal=3");

 // command below extract the categories defined above for the thresholded particles; adjust particle size accordingly - for example set particle size to exclude large features or small

features

 run("Analyze Particles...", "size=10-Infinity circularity=0.00-1.00 show=Nothing summarize");

 selectImage(imagename);

 close();

 } else

 print("Error opening "+path); // outputs an error if the specific folder of images cannot be opened

 }

**Representative output**

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| Slice | Count | Total Area | Average Size | Area Fraction |
| 350C-3-m.tif | 257 | 6051820.413 | 23547.939 | 25.5 |
| 450C-1-m.tif | 263 | 5889404.105 | 22393.172 | 24.8 |
| 450C-2-m.tif | 231 | 6019885.737 | 26060.111 | 25.3 |
| 450C-3-m.tif | 265 | 5986710.223 | 22591.359 | 25.2 |